Řešení úloh z tématického celku funkce s programem Mathematica 


Miroslav Tichý
Střední škola a vyšší odborná škola aplikované kybernetiky
Hradec Králové
tichy@ssakhk.cz

Určete definiční obor funkce f:y=(Sqrt[(2x-1)(x+3)])

f[x_]:=(Sqrt[(2x-1)(x+3)])

Plot[f[x],{x,-5,5}]

Reduce[(2x-1)(x+3)≥0]

Napište rovnici lineární funkce procházející body A, B.

bA={1,1}; bB={3,-7};

lin=y==a*x+b

rov1=lin /.{x->bA[[1]],y->bA[[2]]}

rov2=lin /.{x->bB[[1]],y->bB[[2]]}

linfce=Solve[{rov1,rov2},{a,b}]

lin /.linfce[[1]]

gr1=Plot[5-4x, {x,0,4},AspectRatio->Automatic];

bod=Graphics[{PointSize[0.06],Point[{bA,bB}]}];

Show[gr1,bod]

Sestrojte graf funkce y=a.x - 1 pro měnící se koeficient a.

Manipulate[Plot[a*x-1,{x,-3,3},AspectRatio->Automatic, PlotRange->{{-4,4},{-4,4}}],{a,-3,3,(1/2)}]

Řešte graficky rovnici (Abs[x-3])-3 =x-(Abs[x+2]) .

Solve[x-Abs[x+2]==Abs[x-3]-3]

Show[Plot[{x-Abs[x+2],Abs[x-3]-3},{x,-3,6}],Graphics[{PointSize[0.02],Point[{{2,-2},{4,-2}}]}]]

Určete kvadratickou funkci procházející danými třemi body.

kvf=y==c+b x+a (x^2)

body={{-2,26},{0,4},{1,2}};

rov=Table[y==a*(x^2)+b*x+c /.{x->body[[i,1]],y->body[[i,2]]},{i,1,3}]

koef=Solve[rov,{a,b,c}]

kvf /. koef[[1]]

Show[Plot[4-5 x+3 (x^2),{x,-2.5,3}],ListPlot[body,PlotStyle->PointSize[0.03]]]

Sestrojte graf funkce f: y=2-(Abs[((x+2)/(x+1))]).

Sestrojíme postupnými úpravami:

Plot[((x+2)/(x+1)),{x,-6,2},PlotRange->{-3,5},ExclusionsStyle->Dashed,Exclusions->x==-1]

q1=Plot[((x+2)/(x+1)),{x,-6,2},PlotRange->{-3,5},PlotStyle->RGBColor[1,0,0],ExclusionsStyle->Dashed,Exclusions->x==-1]

q2=Plot[Abs[((x+2)/(x+1))],{x,-6,2},PlotRange->{-3,5},PlotStyle->{RGBColor[0,1,0],Thickness[0.007]}]

q3=Plot[-Abs[((x+2)/(x+1))],{x,-6,2},PlotRange->{-3,5},PlotStyle->{RGBColor[0,1,1],Thickness[0.01]}]

q4=Plot[2-Abs[((x+2)/(x+1))],{x,-6,2},PlotRange->{-3,5},PlotStyle->{RGBColor[0,0,1],Thickness[0.012]}]

Show[q1,q2,q3,q4]

Výsledný graf je zobrazen modře.

Sestrojte inverzní funkci k dané funkci f.

f[x_]:=((x-2)/(2x+1))

Plot[f[x],{x,-5,5},AspectRatio->Automatic,AxesLabel->{x,y}]

rovnice=Solve[x==f[y],y]

g[x_]:=y /. rovnice[[1]]

g[x]

Plot[{f[x],g[x],x},{x,-5,5},AspectRatio->Automatic,AxesLabel->{x,y}]

Určete, zda je daná dvojice funkcí navzájem inverzní.

f1[x_]:=(Sqrt[((5-x)/2)])

f2[x_]:=-2(x^2)+5

Solve[x==f1[y],y]

Plot[{f1[x],f2[x],x},{x,-3,5},AspectRatio->Automatic, PlotStyle->Thick]

Graf goniometrické funkce s posunem
funkce y = A.sin (B.(x + C)) + D.

popis=Table[i*π/3,{i,-3,6}]

{-π,-((2 π)/3),-(π/3),0,(π/3),((2 π)/3),π,((4 π)/3),((5 π)/3),2 π}

Manipulate[Plot[{Sin[x],a*Sin[x]+c},{x,-π,2π},AspectRatio->Automatic,Ticks->{popis,Automatic},PlotStyle->Thickness[0.01]],{a,1,4,1},{c,-2,2}]

TabView[{sin->Manipulate[Plot[{a*Sin[b*(x+c)]+d,Sin[x]},{x,-π,2*π},AspectRatio->Automatic,AxesLabel->{"x","y"},Ticks->{{-2π,-((3π)/2),-π,-(π/2),(π/2),π,((3π)/2),2π},True},PlotStyle->{Thickness[0.005],Hue[.6]},PlotRange->{-5,5},BaseStyle->{Medium,"Label"},ImageSize->{750,500}],{{a,1,"A"},-2,3,Appearance->"Labeled"},{{b,1,"B"},1/2,2,0.1,Appearance->"Labeled"},{{c,0,"C"},-(π/2),(π/2),(π/6),Appearance->"Labeled"},{{d,0,"D"},-3,3,Appearance->"Labeled"}],cos->Manipulate[Plot[{a*Cos[b*(x+c)]+d,Cos[x]},{x,-π,2*π},AspectRatio->Automatic,AxesLabel->{"x","y"},Ticks->{{-2π,-((3π)/2),-π,-(π/2),(π/2),π,((3π)/2),2π},True},PlotStyle->{Thickness[0.005],Hue[.6]},PlotRange->{-5,5},BaseStyle->{Medium,"Label"},ImageSize->{600,400}],{{a,1,"A"},-2,3,Appearance->"Labeled"},{{b,1,"B"},1/2,2,0.1,Appearance->"Labeled"},{{c,0,"C"},-(π/2),(π/2),(π/6),Appearance->"Labeled"},{{d,0,"D"},-3,3,Appearance->"Labeled"}]}]

Dodefinujte  funkční hodnotu funkce y=(((x^2)−1)/((x^3)−1)) tak, aby v bodě 1 byla spojitá.

f[x_]:=(((x^2)−1)/((x^3)−1))

Limit[(((x^2)−1)/((x^3)−1)),x->1]

f[x_]:=Piecewise[{{(((x^2)−1)/((x^3)−1)),x≠1},{(2/3),x==1}}]

f[1]

Plot[f[x],{x,-1,2},AspectRatio->Automatic,Epilog->{Disk[{1,(2/3)},0.03]}]

Řešte rovnici 2*((((1/2)))^((x^2)+(8/3)x))=(8/(4^(1/3))) v R.

Solve[2*((((1/2)))^((x^2)+(8/3)x))==(8/(4^(1/3))),x]

Plot[{2* ((((1/2)))^((x^2)+((8 x)/3))),(8/(4^(1/3)))},{x,-4,4}]

Děkuji za pozornost.